mirror of
https://github.com/davatorium/rofi.git
synced 2024-11-18 13:54:36 -05:00
75ae2a41f0
* implemented xdg thumbnails fetching with fallback on mimetype icons for menu entries in filebrowser mode * included original license text * added md5 header and source file * implemented xdg compatible thumbnail's creation * added -preview-cmd string option to program settings * support custom command to create images for entries with thumbnail:// prefix * fix custom thumbnailer command crash caused by null uri when entry is not a valid filename * check entry_name is not NULL or empty when generating thumbnails; use snprintf to avoid static analyzer complains * avoid using gstrvbuilder to build thumbnailer command args * fixed static analyzer complain about always wrong condition * use g_spawn_check_exit_status to avoid bump to glib 2.70 * removed md5-c dependency and use glib checksum implementation * fixed meson build after md5-c library removal * support thumbnail generation in recursivebrowser mode * restored check rofi_icon_fetcher_file_is_image * create thumbnail directories if not existing * use g_malloc0, g_strdup and g_strdup_printf * fixed formatting with clang-format * don't wait for jobs in execution when finalizing the icon fetcher worker threadpool * destroy and rebuild the icon fetcher worker threadpool when the current page is changed * added query_started boolean member to IconFetcherEntry; check if an icon fetcher query was started on an IconFetcherEntry and submit the query again otherwise * force icon cache lookup even if the item has a valid icon_fetch_uid (the fetching job could have been discarded before starting) * search binaries in PATH when executing thumbnailer command * mark icon query as not started in threadpool item free_func * added listview page_changed_callback; rebuild icon fetcher threadpool in page_changed_callback * [listview] Add missing code documentation param * Create rofi-thumbnails.5.markdown * Updated documentation with apparmor issues and workaround * [Doc] Ship rofi-thumbnails.5 With some formatting fixes * use a more compact thumbnailer example --------- Co-authored-by: giomatfois62 <giomatfois62@yahoo.it> Co-authored-by: Dave Davenport <DaveDavenport@users.noreply.github.com> Co-authored-by: lbonn <github@lbonnans.net>
73 lines
2 KiB
Meson
73 lines
2 KiB
Meson
man_files = [
|
|
'rofi.1',
|
|
'rofi-sensible-terminal.1',
|
|
'rofi-theme-selector.1',
|
|
'rofi-debugging.5',
|
|
'rofi-dmenu.5',
|
|
'rofi-keys.5',
|
|
'rofi-script.5',
|
|
'rofi-theme.5',
|
|
'rofi-thumbnails.5',
|
|
]
|
|
|
|
fs = import('fs')
|
|
|
|
pandoc = find_program('pandoc', required: false, version: '>=2.9')
|
|
|
|
if pandoc.found()
|
|
man_targets = []
|
|
cp_cmds = []
|
|
foreach f: man_files
|
|
section_number = f.split('.')[1]
|
|
install_dest = join_paths(get_option('prefix'), get_option('mandir'), 'man' + section_number)
|
|
|
|
man_targets += custom_target(f,
|
|
input: ['.'.join([f, 'markdown']), 'man_filter.lua'],
|
|
output: f,
|
|
command: [ 'pandoc', '--standalone', '--to=man',
|
|
'--lua-filter', '@INPUT1@',
|
|
'-f', 'markdown-tex_math_dollars',
|
|
'@INPUT0@', '-o', '@OUTPUT@' ],
|
|
install: true,
|
|
install_dir: install_dest,
|
|
build_by_default: true,
|
|
)
|
|
endforeach
|
|
|
|
run_target('generate-manpage', command: ['true'], depends: man_targets)
|
|
else
|
|
man_missing = false
|
|
foreach f: man_files
|
|
if not fs.is_file(f)
|
|
man_missing = true
|
|
endif
|
|
endforeach
|
|
|
|
if man_missing
|
|
warning('Man files cannot be generated and not present in source directory, they will not be installed')
|
|
else
|
|
install_man(man_files)
|
|
endif
|
|
endif
|
|
|
|
doxy_conf = configuration_data()
|
|
doxy_conf.set('PACKAGE', meson.project_name())
|
|
doxy_conf.set('VERSION', meson.project_version())
|
|
doxy_conf.set('abs_builddir', join_paths(meson.project_build_root(), meson.current_build_dir()))
|
|
doxy_conf.set('abs_top_srcdir', meson.project_source_root())
|
|
|
|
doxyfile = configure_file(
|
|
input: 'rofi.doxy.in',
|
|
output: 'rofi.doxy',
|
|
configuration: doxy_conf,
|
|
)
|
|
|
|
doxygen = find_program('doxygen', required: false)
|
|
if doxygen.found()
|
|
html_target = custom_target('doxy',
|
|
input: doxyfile,
|
|
output: 'html',
|
|
command: [doxygen, doxyfile],
|
|
install: false,
|
|
)
|
|
endif
|