mirror of
https://github.com/ruby/ruby.git
synced 2022-11-09 12:17:21 -05:00
ce06c24b0c
Update for autoconf 2.70 --- configure.ac | 232 +++++++++++++++++------------------ tool/m4/ruby_check_builtin_setjmp.m4 | 8 +- tool/m4/ruby_check_printf_prefix.m4 | 9 +- tool/m4/ruby_check_setjmp.m4 | 6 +- tool/m4/ruby_check_sysconf.m4 | 6 +- tool/m4/ruby_cppoutfile.m4 | 4 +- tool/m4/ruby_decl_attribute.m4 | 4 +- tool/m4/ruby_dtrace_available.m4 | 2 +- tool/m4/ruby_dtrace_postprocess.m4 | 2 +- tool/m4/ruby_mingw32.m4 | 4 +- tool/m4/ruby_stack_grow_direction.m4 | 4 +- tool/m4/ruby_try_cflags.m4 | 2 +- tool/m4/ruby_try_cxxflags.m4 | 2 +- tool/m4/ruby_try_ldflags.m4 | 2 +- 14 files changed, 143 insertions(+), 144 deletions(-) Revert AC_PROG_CC_C99 for -std=gnu99 option to gcc 4.8 --- configure.ac | 5 ++++- 1 file changed, 4 insertions(+), 1 deletion(-)
29 lines
1.3 KiB
Text
29 lines
1.3 KiB
Text
# -*- Autoconf -*-
|
|
AC_DEFUN([RUBY_CHECK_PRINTF_PREFIX], [
|
|
AC_CACHE_CHECK([for printf prefix for $1], [rb_cv_pri_prefix_]AS_TR_SH($1),[
|
|
[rb_cv_pri_prefix_]AS_TR_SH($1)=[NONE]
|
|
RUBY_WERROR_FLAG(RUBY_APPEND_OPTIONS(CFLAGS, $rb_cv_wsuppress_flags)
|
|
for pri in $2; do
|
|
AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[@%:@include <stdio.h>
|
|
@%:@include <stddef.h>
|
|
@%:@ifdef __GNUC__
|
|
@%:@if defined __MINGW_PRINTF_FORMAT
|
|
@%:@define PRINTF_ARGS(decl, string_index, first_to_check) \
|
|
decl __attribute__((format(__MINGW_PRINTF_FORMAT, string_index, first_to_check)))
|
|
@%:@else
|
|
@%:@define PRINTF_ARGS(decl, string_index, first_to_check) \
|
|
decl __attribute__((format(printf, string_index, first_to_check)))
|
|
@%:@endif
|
|
@%:@else
|
|
@%:@define PRINTF_ARGS(decl, string_index, first_to_check) decl
|
|
@%:@endif
|
|
PRINTF_ARGS(void test_sprintf(const char*, ...), 1, 2);]],
|
|
[[printf("%]${pri}[d", (]$1[)42);
|
|
test_sprintf("%]${pri}[d", (]$1[)42);]])],
|
|
[rb_cv_pri_prefix_]AS_TR_SH($1)[=[$pri]; break])
|
|
done)])
|
|
AS_IF([test "[$rb_cv_pri_prefix_]AS_TR_SH($1)" != NONE], [
|
|
AC_DEFINE_UNQUOTED([PRI_]m4_ifval($3,$3,AS_TR_CPP(m4_bpatsubst([$1],[_t$])))[_PREFIX],
|
|
"[$rb_cv_pri_prefix_]AS_TR_SH($1)")
|
|
])
|
|
])dnl
|