mirror of
https://github.com/ruby/ruby.git
synced 2022-11-09 12:17:21 -05:00
c5fe904f6e
* coroutine/win32/Context.asm: old ml version 9 needs CPU directive before `.model` directive. * win32/Makefile.sub: specify object directories to separate Win32 and Win64 targets. Win32 rule was overridden by Win64 rule and just ignored. git-svn-id: svn+ssh://ci.ruby-lang.org/ruby/trunk@66059 b2dd03c8-39d4-4d8f-98ff-823fe69b080e
55 lines
1 KiB
NASM
55 lines
1 KiB
NASM
;;
|
|
;; This file is part of the "Coroutine" project and released under the MIT License.
|
|
;;
|
|
;; Created by Samuel Williams on 10/5/2018.
|
|
;; Copyright, 2018, by Samuel Williams. All rights reserved.
|
|
;;
|
|
|
|
.386
|
|
.model flat
|
|
|
|
.code
|
|
|
|
assume fs:nothing
|
|
|
|
; Using fastcall is a big win (and it's the same has how x64 works).
|
|
; In coroutine transfer, the arguments are passed in ecx and edx. We don't need
|
|
; to touch these in order to pass them to the destination coroutine.
|
|
|
|
@coroutine_transfer@8 proc
|
|
; Save the thread information block:
|
|
push fs:[0]
|
|
push fs:[4]
|
|
push fs:[8]
|
|
|
|
; Save caller registers:
|
|
push ebp
|
|
push ebx
|
|
push edi
|
|
push esi
|
|
|
|
; Save caller stack pointer:
|
|
mov dword ptr [ecx], esp
|
|
|
|
; Restore callee stack pointer:
|
|
mov esp, dword ptr [edx]
|
|
|
|
; Restore callee stack:
|
|
pop esi
|
|
pop edi
|
|
pop ebx
|
|
pop ebp
|
|
|
|
; Restore the thread information block:
|
|
pop fs:[8]
|
|
pop fs:[4]
|
|
pop fs:[0]
|
|
|
|
; Save the first argument as the return value:
|
|
mov eax, dword ptr ecx
|
|
|
|
; Jump to the address on the stack:
|
|
ret
|
|
@coroutine_transfer@8 endp
|
|
|
|
end
|