gitlab-org--gitlab-foss/app/assets/javascripts/line_comments/services/resolve.js.coffee

class ResolveService
  constructor: ->
    actions = {
      resolve:
        method: 'POST'
        url: 'notes{/id}/resolve'
      all:
        method: 'POST'
        url: 'notes/resolve_all'
    }

    Vue.http.headers.common['X-CSRF-Token'] = $.rails.csrfToken()
    @resource = Vue.resource('notes{/id}', {}, actions)

  resolve: (namespace, discussionId, noteId, resolve) ->
    Vue.http.options.root = "/#{namespace}"
    @resource
      .resolve({ id: noteId }, { discussion: discussionId, resolved: resolve })
      .then (response) ->
        if response.status is 200
          CommentsStore.update(discussionId, noteId, resolve)

  resolveAll: (namespace, discussionId, allResolve) ->
    Vue.http.options.root = "/#{namespace}"

    ids = []
    for noteId, resolved of CommentsStore.state[discussionId]
      ids.push(noteId) if resolved is allResolve

    @resource
      .all({}, { ids: ids, discussion: discussionId, resolved: !allResolve })
      .then (response) ->
        if response.status is 200
          for noteId in ids
            CommentsStore.update(discussionId, noteId, !allResolve)

$ ->
  @ResolveService = new ResolveService()